Серый Хомячок

  • Увеличить размер шрифта
  • Размер шрифта по умолчанию
  • Уменьшить размер шрифта

Еще чуть чуть про Mikrotik

E-mail Печать

Превращаем умный рутер Mikrotik в глупый свич, который будет лучить в эфир Wi-Fi.

Все растут и я расту. Отхомячил себе каморку, решил туда спрятаться, но вот незадача - телефон не ловит интернет, далеко, даже если дунуть в Wi-Fi целый Ватт мощности. Изобретать внешние антенны, паяться пигтейлами, которые еще и купить в Китае надо? Долго и работать надо, а в соседней лавке незадорого дают самый маленькие Микротики. Как раз самое оно: проводульки из старого свича повтыкать в микротык и файлик текстовый написать за две минуты.

Будем иметь ввиду, что все происходит в ЛАНе 10.0.0.0/24, где интернет раздается с адреса 10.0.0.1, адреса ДНС и серверов времени я оставил свои. Да, картинок не будет. Будут скучные строки кода. За минимальными картинками советую сходить сюда.

Того задача: нужно чтобы у новой железяки был свой Ай-Пи, так мне будет удобнее заходить в нее, нужно что бы все порты работали свичем, нужно что бы железяка раздавала интернет по воздуху.

Первым делом подключаемся Винбоксом и сносим конфигурацию, нужно выбрать в меню System->Reset Configuration и поставить галочку в чекбокс No Default Configuration и нажать Reset Configuration.

Рутер чист, соберем в нем свич из всех портов:

/interface ethernet
set [ find default-name=ether1 ] comment=LAN1
set [ find default-name=ether2 ] master-port=ether1 comment=LAN2
set [ find default-name=ether3 ] master-port=ether1 comment=LAN3
set [ find default-name=ether4 ] master-port=ether1 comment=LAN4

Соберем мост между рутером и вайрлессом, так как у нас все порты соеденены в кучу подключаем только первый:

/interface bridge
add name=bridge1
/interface bridge port
add bridge=bridge1 interface=ether1
add bridge=bridge1 interface=wlan1

Присвоим первому порту адрес (у меня для таких железок первые десять адресов зарезервированы, чего и вам желаю), пропишем гейт и ДНСы:

/ip address
add address=10.0.0.9/24 interface=ether1 network=10.0.0.0
/ip route add comment=GATEWAY distance=1 gateway=10.0.0.1
/ip dns set allow-remote-requests=yes servers=91.198.156.20,159.148.60.20,159.148.60.2
/ip dns set allow-remote-requests=yes

Если не нужен статичный адрес и есть DHCP в сети, то можно это все заменить вот таким:

/ip dhcp-client
add dhcp-options=hostname,clientid disabled=no interface=ether1
/ip dns
set allow-remote-requests=yes

Включаем Wi-Fi:

/interface wireless
set [ find default-name=wlan1 ] adaptive-noise-immunity=ap-and-client-mode band=2ghz-b/g/n \
channel-width=20/40mhz-Ce country=_ВАША_СТРАНА_ disabled=no distance=indoors frequency=_НУЖНАЯ_ЧАСТОТА_КАНАЛА_ \
hw-protection-mode=rts-cts l2mtu=1600 mode=ap-bridge rx-chains=0,1 tx-chains=0,1 tx-power=7 \
tx-power-mode=all-rates-fixed wireless-protocol=802.11 wmm-support=enabled ssid=_ИМЯ_СЕТИ_

Включаем паролирование:

/interface wireless security-profiles
set [ find default=yes ] authentication-types=wpa-psk,wpa2-psk mode=dynamic-keys \
wpa-pre-shared-key=_ПАРОЛЬ_ wpa2-pre-shared-key=_ПАРОЛЬ_

Наладим часики, присвоим железке имя, чтобы не путаться. У меня их уже пять штук, без имен стало сложновато. Поставим номинальную частоту процессора, если загрузки нет, то можно меньше поставить, если все время загрузка полная, то можно попробовать поднять, я не пробовал:

/system clock
set time-zone-name=_ВАША_ЧАСОВАЯ_ЗОНА_
/system ntp client
set enabled=yes primary-ntp=85.254.216.1 secondary-ntp=212.83.133.52
/system identity
set name=_ИМЯ_ЖЕЛЕЗЯКИ_
/system routerboard settings
set cpu-frequency=650MHz protected-routerboot=disabled

И теперь главное: ведь как известно параноя не означает, что за мной никто не следит. Хоть новая железка и будет сидеть внутри ЛАНа, но по воздуху она будет видна. Убъем дефолтного админа, закроем все порты, весь доступ, кроме Винбокса на второй порт - туда будет воткнут птчкорд машины, с которой мы будет заходить, прикроем обнаружение соседей:

/ip firewall service-port
set ftp disabled=yes
set tftp disabled=yes
set irc disabled=yes
set h323 disabled=yes
set sip disabled=yes
set pptp disabled=yes
/ip service
set telnet disabled=yes
set ftp disabled=yes
set www disabled=yes
set ssh disabled=yes
set api disabled=yes
set winbox address=10.0.0.0/24
set api-ssl disabled=yes
/tool
mac-server set [ find default=yes ] disabled=yes
mac-server mac-winbox set [ find default=yes ] disabled=yes
mac-server mac-winbox add interface=ether2
/ip neighbor discovery set bridge1 discover=no
/ip neighbor discovery set ether1 discover=no
/ip neighbor discovery set ether2 discover=no
/ip neighbor discovery set ether3 discover=no
/ip neighbor discovery set ether4 discover=no
/ip neighbor discovery set wlan1 discover=no
/user
add name=_ИМЯ_АДМИНА_ password=_ПАРОЛЬ_АДМИНА_ group=full address=10.0.0.0/24
disable admin

 Почему все отключаем в конце? Просто нужно чтобы имена интерфейсов уже был в системе, иначе не получится.

Ну вот и все, если есть ошибки, то сообщайте, я исправлю.


back_to_top02

Обновлено 08.10.2015 16:07  

Баннер
Баннер
mod_vvisit_countermod_vvisit_countermod_vvisit_countermod_vvisit_countermod_vvisit_countermod_vvisit_countermod_vvisit_counter
Сейчас 70 гостей онлайн
Просмотры материалов : 1298893
Разработано "Marine Standard" SIA © 2009